内容目录

前言

MAC 地址（Media Access Control Address），也称为局域网地址（LAN Address）、以太网地址（Ethernet Address）或物理地址（Physical Address），它是一个用来确认网络设备身份的标识符。

在日常工作、学习中，经常需要查询电脑的固定网卡MAC地址信息，使用手动方法，需要一定电脑知识。而使用批处理脚本，可以更容易（即便是电脑新手，只需要双击运行即可。免除了繁复的教学培训过程）。

运行效果

下图为批处理脚本查询的效果展示：

查询电脑固定网卡MAC地址信息(包括蓝牙) — 如图，共查询到3条MAC地址信息：第一条为无线网卡、第二条为以太网、第三条为蓝牙。不包括虚拟网卡信息。

脚本内容

@echo off
title 查询当前电脑所有固定网卡MAC地址(包括蓝牙)信息 By:迷路轮回
setlocal enabledelayedexpansion
mode con cols=80 lines=25

echo=&echo=&echo=
call :Title&echo=&echo=
echo=      查询时间：%date% %time%
echo=      电脑名称：!computername!
echo=

set Getnic=WMIC nic WHERE ( PNPDeviceID LIKE "PCI%%" OR PNPDeviceID LIKE "BTH%%" ) GET Name,MACAddress
echo       MAC地址            网卡名称
for /f "skip=1 tokens=1,2,3,4,5,6,7-99 delims=," %%i in ( '!Getnic!' ) do ( echo=      %%i)
echo=&call :By&echo=&call :exit
pause >nul

:Title
set /p=		    <nul
set b=查询当前电脑&set c=固定网卡&set d=MAC地址(包括蓝牙)信息
pushd "%temp%" & set/p=<nul>%b%& findstr /a:0e .* %b% nul&del %b%  & popd
pushd "%temp%" & set/p=<nul>%c%& findstr /a:0a .* %c% nul&del %c%  & popd
pushd "%temp%" & set/p=<nul>%d%& findstr /a:0e .* %d% nul&del %d%  & popd
echo= & goto :eof

:By
set /p=					<nul
set b=迷路轮回 & set c=2022-05-16 & set d=xyx115.com
pushd "%temp%" & set/p=<nul>%b%& findstr /a:0b .* %b% nul&del %b% & popd
pushd "%temp%" & set/p=<nul>%c%& findstr /a:0b .* %c% nul&del %c% & popd
pushd "%temp%" & set/p=<nul>%d%& findstr /a:0b .* %d% nul&del %d% & popd
echo= & goto :eof

:Exit
set /p=<nul&set b=请按任意键退出！
pushd "%temp%" & set/p=<nul>%b%& findstr /a:0c .* %b% nul&del %b% & popd
echo= & goto :eof

脚本说明

脚本功能

用于查询当前电脑的固定网卡信息。

包括：

电脑主板自带的无线、有线网卡
PCI形式安装到电脑上的网卡

不包括：

USB形式的无线、有线网卡
软件虚拟的网卡，例如VMware、Hyper-V等

脚本特点

使用简单方便，即便是电脑新手不需要任何培训，亦可顺利完成MAC地址信息查询。
运行稳定可靠，借助windows 电脑原生支持的批处理脚本，进行系统信息安全可靠的查询。
可列出所有固定网卡信息（包括蓝牙信息），且排除USB网卡、虚拟机网卡
界面展示友好

使用范围

此脚本可以在windows 电脑上正常运行。包括：windows xp、windows 7、windows 8、windows 10、windows 11、windows server 系列

脚本下载

直接下载

查询当前电脑所有物理网卡MAC地址（包括蓝牙）-v3.5.bat_下载

手动创建

新手可以参考创建批处理脚本的4种方法 – 迷路轮回 (xyx115.com)文章中的方法1或方法2。或者直接下载，然后解压。

更多用法

此脚本稍作修改，可以仅查询本机网卡MAC信息（，仅包括固定网卡，不包括蓝牙），方法：

原文：( PNPDeviceID LIKE "PCI%%" OR PNPDeviceID LIKE "BTH%%" )
变更：( PNPDeviceID LIKE "PCI%%" )

也可以修改为查询所有网卡MAC地址信息，查询所有网卡MAC时，列表较长，因此需要增加显示长度，或者也可以直接删除lines=25，方法：

原文1：mode con cols=80 lines=25
变更1：mode con cols=80 lines=35

原文2：WMIC nic WHERE ( PNPDeviceID LIKE "PCI%%" OR PNPDeviceID LIKE "BTH%%" ) GET Name,MACAddress
变更2：WMIC nic GET Name,MACAddress

添加判断条件，可以进一步限制需要查询的网卡信息

WMIC nic WHERE ( PNPDeviceID LIKE "PCI%%" OR PNPDeviceID LIKE "BTH%" and netenabled="true") GET Name,MACAddress

rem 上述查询意为：查询网卡PNPDeviceID以PCI开头的网络信息和网卡PNPDeviceID以BTH开头且网卡处于活动状态的的网络信息，即：此处对网卡PNPDeviceID以BTH开头的网络设备添加了查询限制条件。

WMIC nic WHERE ( PNPDeviceID LIKE "PCI%%" and netenabled="true" OR PNPDeviceID LIKE "BTH%" and netenabled="true") GET Name,MACAddress
rem 上述查询意为：查询网卡PNPDeviceID以PCI开头且网卡处于活动状态的网络信息和网卡PNPDeviceID以BTH开头且网卡处于活动状态的的网络信息，即：此处对两种网络设备均添加了查询限制条件。

前言